Lecture des métadonnées avec VBScript (VBS)

Set Args = WScript.Arguments

'On prend les deux arguments'
foldername = Args(0)
filename = Args(1)

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(foldername)

'Métadonnées sous forme de (clé, valeur)'
Set objMetadata = CreateObject("Scripting.Dictionary")

'Récupération du fichier'
Set item = objFolder.ParseName(filename)

   'Nombre de colonnes (de 0 à 320) des détails (par exemple : Titre, Album, Taille du fichier... etc)'
   For i = 0 To 320

      'On lit les détails à la colonne i'
      details = objFolder.GetDetailsOf(item, i)

      'Si les détails ne sont pas vides'
      If Trim(details) <> "" Then
         'On enregistre clé et la valeur. Exemple "Titre: Mon Titre"'
         objMetadata.Add objFolder.GetDetailsOf(objFolder.Items, i), details
      End If

   Next

'Format Clé: Valeur (exemple : Titre: Titre de la musique)'
formattedString = ""
   For Each key in objMetadata 
      formattedString = formattedString & vbCRLF & key & ": " & objMetadata(key)
   Next
wscript.echo formattedString

Pour exécuter le script vous devez renseigner le chemin du dossier et le nom du fichier comme ceci :

cscript metadata.vbs "C:\chemin\vers\le\dossier" "nom_du_fichier"

Ou en mode graphique :

wscript metadata.vbs "C:\chemin\vers\le\dossier" "nom_du_fichier"